Skychart

Cette page est en lecture seule. Vous pouvez afficher le texte source, mais ne pourrez pas le modifier. Contactez votre administrateur si vous pensez qu'il s'agit d'une erreur.
====== Exemple de script ======

Cette page donne des conseils et des exemples de script. \\
Vous pouvez également regarder le code des [[toolbox|boîte à outils standard]]  à partir du programme. \\
Pour plus de détails sur une fonction spécifique, voir la page de [[script_reference|référence des script]].


===== Généralités =====

Nous examinons d'abord en détail le code du bouton Goto de la boîte à outils standard pour l'observation. \\
Cela couvre de nombreuses bases de programmation.

Le code complet du script ressemble à ceci:
<code>
// Slew telescope
  var ra,de: double;
      a,b,r: string;
      c: Tstringlist;
  begin
  memo_1.clear;
  if MenuTelescopeConnect.checked then begin
    if not StrToAR(Edit_1.text,ra) then begin memo_1.lines.add(rserror+' RA!');exit;end;
    if not StrToDE(Edit_2.text,de) then begin memo_1.lines.add(rserror+' DE!');exit;end;
    a:=floattostr(ra);
    b:=floattostr(de);
    GetSL('STRL1',c);
    c.clear;
    c.add('SLEW');
    c.add(a);
    c.add(b);
    r:=cmd('',c);
    c.clear;
    memo_1.lines.add(r);
  end
  else memo_1.lines.add(rsTelescopeNot);
  end.
</code>  

Regardons chaque partie en détail:
<code>
// Slew telescope
</code>
C'est un commentaire, vous pouvez utiliser <nowiki>// {..} (*..*)</nowiki> pour marquer les commentaires.

----

<code>
  var ra,de: double;
      a,b,r: string;
      c: Tstringlist;
</code>
Définit les variables que nous utiliserons plus loin dans le script.\\
Les types de variable important sont: integer, double, string.\\
Le type Tstringlist est utilisé pour envoyer des commandes à Cartes du Ciel.

----

<code>
  begin
</code>
Le début de notre programme.

----

<code>
memo_1.clear;
</code>
Efface la zone de texte que nous utilisons pour afficher les messages. Cela garantit que la zone de texte n'est pas remplie par les messages précédents.

----

<code>
  if MenuTelescopeConnect.checked then begin
</code>
Nous testons la propriété Checked de l'élément de menu MenuTelescopeConnect. Ceci indique que nous avons connecté le télescope. \\
Si le résultat est vrai, nous exécutons le bloc de code commençant par "begin" jusqu'à "end" correspondant.

----

<code>
    if not StrToAR(Edit_1.text,ra) then begin memo_1.lines.add(rserror+' RA!');exit;end;
</code>
Nous essayons de convertir RA du format HMS de la zone de texte Edit_1 dans une valeur numérique. Si la conversion échoue (parce que nous tapons n'importe quoi dans la zone de texte) nous affichons un message d'erreur et nous quittons.

----

<code>
   a:=floattostr(ra);
</code>
Conversion de RA à nouveau en chaîne de caractères mais avec le format décimal requis par la commande.

----

<code>
GetSL('STRL1',c);
c.clear;
</code>
Demande un objet TStringList identifié par STRL1. Nous effaçons toutes les données qui peuvent rester dans l'objet.

----

<code>
    c.add('SLEW');
    c.add(a);
    c.add(b);
</code>
Ajoutez la commande et les paramètres requis (dans ce cas, RA et DEC) à la liste de chaînes.

----

<code>
   r:=cmd('',c);
</code>
Exécute la commande et stocke le résultat dans la variable r.

----

<code>
memo_1.lines.add(r);
</code>
Affiche le résultat de la commande dans la zone de texte.

----

<code>
else memo_1.lines.add(rsTelescopeNot);
</code>
Dans le cas où le test MenuTelescopeConnect.checked est faux, nous exécutons cette ligne. \\
Il affiche dans la zone de texte une traduction dans la langue locale de 'Télescope non connecté'.

----

<code>
 end.
</code>
La fin du programme.


===== Appel d'une librairie externe ====

Vous pouvez définir une fonction dans une librairie externe à utiliser dans votre script comme une autre fonction locale.

Cet exemple implémente un chronomètre simple en utilisant la fonction GetTickCount de l'API Windows. \\
Il y a deux boutons Start et Stop et deux zone de texte. Une variable globale integer est utilisée pour stocker l'heure de début.

Script du bouton Start:
<code>
 function GetTickCount: Longint; external 'GetTickCount@kernel32.dll stdcall';
 var
   tick: Longint;
 begin  
   tick:=GetTickCount;
   setI('Int1',tick);
   edit_1.text:='Started';
 end.
</code>

Script du bouton Stop:
<code>
function GetTickCount: Longint; external 'GetTickCount@kernel32.dll stdcall';
var
  t: double;
  t1,tick: Longint;
begin
  tick:=GetTickCount;
  getI('Int1',t1);
  t:=double(tick-t1)/1000;
  edit_1.text:='';
  edit_2.text:=formatdatetime('HH:MM:SS.ZZZ',t/24/3600);
end.
</code>

Vous pouvez appeler n'importe quelle fonction d'un librairie de cette façon, mais méfiez-vous que cela dépend du système, la librairie kernel32.dll n'est pas disponible sur Mac ou Linux.

Une autre limitation est que beaucoup de fonctions de librairie attendent un pointeur vers une structure de paramètre. Comme le langage de script utilise un byte code en interne (comme Java), il ne peut pas utiliser un pointeur pour donner les paramètres. Une solution est d'écrire un wrapper en C qui exporte la fonction avec une liste de paramètres à plat.

===== Utiliser ASCOM directement ==== 

Cela décrit comment utiliser un périphérique ASCOM directement à partir de votre script sans utiliser le télescope ASCOM de Cartes du Ciel.

Il peut être utilisé pour accéder à une autre classe de périphérique, l'exemple se connecte à un dôme, ou pour accéder à des propriétés supplémentaires de votre télescope. \\
Dans ce dernier cas, vous devez faire attention que votre script fonctionne en concurrent du programme principal pour l'accès au périphérique.

==== Choisir un périphérique ASCOM  ===

Le code suivant assigné à un bouton permet de sélectionner le pilote ASCOM Dome que nous voulons utiliser. Le nom du pilote est enregistré dans le champ de texte Edit_1.

<code>
 var
   V: variant;
   w,s: widestring;
 begin
   V := CreateOleObject('ASCOM.Utilities.Chooser');
   w:='Dome';
   V.DeviceType:=w;
   s:=edit_1.text;
   s:=V.Choose(s);
   edit_1.text:=s;
   V:=Unassigned;
 end.
</code>

Remplacer w:='Dome'; par Telescope, Focuser, Rotator, Camera, Filter pour choisir un autre type de périphérique.
 
==== Connecter le pilote ASCOM ===

Le code suivant est pour le bouton "Connecter". Il se connecte au pilote ASCOM Dome que nous avons sélectionné précédemment. Nous utilisons la variable globale Dome1 pour stocker l'objet ASCOM.
<code>
var
  D: variant;
  s: widestring;
begin
  s:=edit_1.text;
  getV('Dome1',D);
  if VarIsEmpty(D) then
    D := CreateOleObject(s);
  D.connected:=true;
  setV('Dome1',D);
end.
</code>

==== Utilisation du pilote ASCOM ===

Maintenant, nous voulons ajouter un bouton pour ouvrir le volet du dôme. C'est juste un exemple, à ce stade, n'importe quelle propriété ASCOM peut être utilisée. \\
Le premier test protège d'un blocage du programme si nous essayons d'utiliser une variante non initialisée. \\
Le deuxième test protège d'une erreur ASCOM si le dôme n'est pas connecté.
<code>
var
  D: variant;
begin
  getV('Dome1',D);
  if (not VarIsEmpty(D)) then
    if D.Connected then
       D.OpenShutter;
end.
</code>

==== Déconnexion du pilote ASCOM ===

Ajout d'un bouton pour déconnecter le pilote et libérer les ressources.
<code>
var
  D: variant;
begin
  getV('Dome1',D);
  if (not VarIsEmpty(D)) then
    if D.Connected then
       D.connected:=false;
  D:=Unassigned;
  setV('Dome1',D);
end.
</code>

===== Ouvrir un document =====

Le code suivant ouvre la documentation de Cartes du Ciel dans le navigateur Web par défaut. \\
Vous pouvez utiliser n'importe quel type de document avec cette fonction, le document sera ouvert avec l'application par défaut de la même manière que si vous double-cliquez sur le document dans l'explorateur de fichiers.

<code>
begin
  OpenFile('doc\wiki_doc\en\documentation\start.html');
end.
</code>

===== Exécuter une commande =====

Il existe deux façons différentes d'exécuter une commande externe ou un programme, selon si vous voulez attendre un résultat ou non.

==== Avec attente du résultat ====

Le code suivant exécute la commande DIR dans le répertoire courant. Le résultat est stocké dans une liste de chaînes et affiché plus tard dans un mémo texte. Il contient la liste des fichiers du répertoire.

<code>
var r:TstringList;
begin
  GetSL('STRL1',r);
  r.clear;
  RunOutput('dir',r);
  Memo_1.lines.assign(r);
end.
</code>

==== Sans attente ====

Si la commande peut s'exécuter pendant un temps indéterminé ou ne produit pas un résultat, vous devez utiliser le code suivant. \\
Cet exemple exécute le programme "Variable star observer" et quitte immédiatement.
<code>
begin
  Run('varobs');
end.
</code>